$MediaCheck = 2
;****************************************************************************
;**************************** H E A D E R  **********************************
;****************************************************************************
;**                                                                        **
;**  TITLE:        Install.jcl for CTOS OSI TransportLAN R2.4             **
;**                                                                        **
;**  FILE ID:      [B25OTL1]<Sys>Install.jcl                              **
;**                                                                        **
;**  FUNCTION:     This Job Control Language (jcl) script file will        **
;**                install the COTL R2.4 to hard disk from floppy          **
;**                using Installation Manager.                             **
;**                                                                        **
;**  INPUT:        None.                                                   **
;**                                                                        **
;**  OUTPUT:       None.                                                   **
;**                                                                        **
;**  CALLED BY:    Installation Manager, Floppy Install                    **
;**                                                                        **
;**  CALLSUSES:   [B25OTL1]<Sys>Install.ctrl                             **
;**                                                                        **
;**  ASSUMPTIONS:  Installation Manager is present on the system that      **
;**                COTL R2.4 is going to be installed on.                  **
;**                                                                        **
;****************************************************************************
;*********************  NATIONALIZATION INSTRUCTIONS    *********************
;****************************************************************************
;**                                                                        **
;**  1) Search for ;NATIONALIZABLE STRINGS                                 **
;**     Nationalize stings listed below the ;NATIONALIZABLE STRINGS marker **
;**                                                                        **
;**  2) Search for ;NATIONALIZE                                            **
;**     Nationalize the text below the ;NATIONALIZE marker                 **
;**                                                                        **
;**  Added UnaAtended mode operation  Alka Rao 092993                 **
;****************************************************************************

$Job InstCOTL
$RestartLabel
$PauseOff

a = 0
b = 0

;NATIONALIZABLE STRINGS:

RelMsg = 'Are you interested in the Release Notes?'
RifViewMsg = 'Do you wish to view the Release Notes at this time?'
RifPrintMsg = 'Do you wish to print the Release Notes at this time?'
PtrNameMsg = 'Enter printer name and press GO.'
CnclMsgSTI = 'Installation of STI cancelled.'
CheckingSTI = 'Comparing system and installation STI versions.'
CmdMsg = 'Adding commands ... '
OldSTIRnFil = '[Sys]<Sys>STI.run'
RequestMsg = 'Updating the Request file.  Please wait ... '
WarningMsg = 'Choose YES to overwrite the newer version'
CpyMsg = 'Copying the CTOS files to hard disk.  Please wait ... '
CpyCnfgPrmpt = 'Overwrite the current configuration files on hard disk?  '
FloppySpec = 'COTL Disk 2 of 2'
OsiCnfgFile = '[Sys]<Sys>OsiLocalNSAPCnfg.sys'
OsiCnfgTFile = '[Sys]<Sys>OsiTransNetCnfg.sys'
STICnfgFile = '[Sys]<Sys>STICnfg.sys'

;NATIONALIZABLE STRINGS (PROTOCOL MANAGER):

;MCF = 'Merge Command Files'


	VidLev = 0

    ; initialize variables

    TRUE        = 1
    FALSE       = 0
    CLSTRLFS    = 2
    LocalSpec   = '[Sys]<Sys>'
    ServerSpec  = '[Sys]<Sys>'
    SWInstal    = 0
;	SwdDir		= '[Sys]<LcnCOTL>'

    ;Determine whether to install files to the server or to the local disk


    $If Public ; If a server
        DestPath = ServerSpec
        DefVol   = '[Sys]'

    $Else ;Not a server
        DestPath = LocalSpec
        DefVol   = '[Sys]'
    $EndIf ;If Public


    ; Define what the InstallFrom Directories are

	$IF InstallType  = 0 ; Install From Floppy
         FromSys     = ConcatStrings(DeviceFrom,'<Sys>')
         FromUNISYS  = ConcatStrings(DeviceFrom,'<UNISYS>')
     $EndIf
   
     $IF InstallType = 2 ; Install From Server
          FromSys    = ConcatStrings(DeviceFrom,'<Sys>')
          FromUNISYS = ConcatStrings(DeviceFrom,'<Sys>')
     $EndIf

     $IF InstallType = 4 ; Software Distribution Installation
          FromSys    = DeviceFrom
          FromUNISYS = DeviceFrom
          SWInstal = 1
     $EndIf

	$If Unattended and InstallType > 0; unattended and not floppy
    	SWInstal = 1
	$EndIf



	;******************************************************************
	;      Scroll lines on screen and print copyright information
	;******************************************************************

    ; Scroll four lines on the screen so messages look better

    i = 0
    $While (i < 4)
        i = i + 1
        $DisplayLine
    $EndWhile

$RestartLabel


	i = 0
	$While (i < 10)
	i = i + 1
	$DisplayLine
	$EndWhile

;NATIONALIZE THE NEXT 15 LINES
$Displayline ('                     CTOS OSI Transport LAN 2.4              ')
$Displayline ('                                                             ')
$Displayline ('                    PROPRIETARY PROGRAM MATERIAL             ')
$Displayline ('                                                             ')
$Displayline ('        This material is Proprietary to Unisys Corporation   ')
$Displayline ('        and is not to be reproduced, used or disclosed except')
$Displayline ('        in accordance with program license or upon written   ')
$Displayline ('        authorization of Unisys Corporation.                 ')
$Displayline ('                                                             ')
$Displayline ('        COPYRIGHT (C) 1993 UNISYS CORPORATION.               ')
$Displayline ('        All Rights Reserved                                  ')
$Displayline ('        UNISYS PROPRIETARY                                   ')
$Displayline ('                                                             ')
$Displayline ('                        Press AEGOAA to continue.          ')

;The use of DisplayandWait will cause hang in unattended.
;To avoid it: Added $If  ADR 092993

$If not Unattended
$DisplayandWait 
$EndIf

	i = 0
	$While i < 20
		i = i + 1
		$DisplayLine
	$EndWhile

$RestartLabel

$If Public

;Copy For Server Installation

;NATIONALIZE COMMAND NAME (COPY) IF NECESSARY:
$RUN [Sys]<Sys>Lcopy.run,COTLReleaseNotes.doc,FromSys,DestPath,,yes,,no

$EndIf       ;If Public


; Ask about the release notes

$If not Unattended

Release = UserSelectYesNo (RelMsg,'No')
$If Release

    RIFView = UserSelectYesNo(RIFViewMsg,'No')

    $If RIFView
    i = 0
    $While (i < 20)
        i = i + 1
        $DisplayLine
    $EndWhile

        $PauseOn

          Notes = ConcatStrings(FromSys,'COTLReleaseNotes.doc')

;NATIONALIZE COMMAND NAME (COPY) IF NECESSARY:
$Command Copy,Notes,[vid],yes
        $PauseOff

    $EndIf     ;If RIFView

    RIFPrint = UserSelectYesNo(RIFPrintMsg,'No')

    $If RIFPrint
    i = 0
    $While (i < 4)
        i = i + 1
        $DisplayLine
    $EndWhile

        PrintName = $UserEnterValue(PtrNameMsg)
        P = $ConcatStrings('[',PrintName)
        P1 = $ConCatStrings(P,']')

;NATIONALIZE COMMAND NAME (COPY) IF NECESSARY:
$Command Copy,Notes,P1
    $EndIf        ;$If RIFPrint

$ENDIF   ;If Release

$ENDIF	;If  not Unattended

$RestartLabel

;NATIONALIZE the next 3 lines:        
$Displayline ('          At this time power down all Cluster Stations.')
$Displayline ('                                                       ')
$Displayline ('                      Press AEGOAA to continue.      ')

$If not Unattended
$DisplayandWait 
$EndIf

	i = 0
	$While i < 20
		i = i + 1
		$DisplayLine
	$EndWhile

$Display (CpyMsg)

$If Public

;Copy files to the <Sys> directory, to be used by Install from Server

$Run [Sys]<Sys>Lcopy.run,BOTL.cmds,FromSys,DestPath,,yes,,no


;NATIONALIZE COMMAND NAME (DELETE) IF NECESSARY:

$Command Delete,[Sys]<Sys>InstallBOTL.run
$Command Delete, [Sys]<Sys>BOTL.run
$Run [Sys]<Sys>Lcopy.run,OSITransnet.run,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,InstallTransnet.run,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,BOTLConfig.run,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,LDM.run,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,BOTLConfigMsg.bin,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,LDMTxt.bin,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,OSIMsg.bin,FromUNISYS,DestPath,,yes,,no

$Else

;NATIONALIZE COMMAND NAME (DELETE) IF NECESSARY:

$Command Delete,[Sys]<Sys>InstallBOTL.run
$Command Delete,[Sys]<Sys>BOTL.run
$Run [Sys]<Sys>Lcopy.run,OSITransnet.run,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,InstallTransnet.run,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,BOTLConfig.run,fromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,LDM.run,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,BOTLConfigMsg.bin,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,LDMTxt.bin,FromUNISYS,DestPath,,yes,,no
$Run [Sys]<Sys>Lcopy.run,OSIMsg.bin,FromUNISYS,DestPath,,yes,,no

$EndIf ;If Public

;NATIONALIZE done.

$Displayline (' done.')

$DisplayLine

$RestartLabel

$Display (CmdMsg)

$If Public

;Remove the commands from sys.cmds

        CmdFileTo = '[Sys]<Sys>sys.cmds'

$Run ([Sys]<Sys>CmdFileEditor.run, 'Remove Command', 'RC'),  
      'Install OSI Transnet', CmdFileTo, yes, DefVol
$Run ([Sys]<Sys>CmdFileEditor.run, 'Remove Command', 'RC'),  
      'Deinstall OSI Transnet', CmdFileTo, yes, DefVol
$Run ([Sys]<Sys>CmdFileEditor.run, 'Remove Command', 'RC'),  
      'COnfigure OSI Transnet', CmdFileTo, yes, DefVol
$Run ([Sys]<Sys>CmdFileEditor.run, 'Remove Command', 'RC'),  
      'LAN Diagnostic Monitor', CmdFileTo, yes, DefVol

;Now add commands to cluster.cmds

        CmdFileTo = '[Sys]<Sys>Cluster.cmds'

$EndIf    

BOTL_cmds = ConcatStrings(FromSys, 'BOTL.cmds')
$Run ([Sys]<Sys>CmdFileEditor.run, 'Merge Command Files', 'MC'),  
      BOTL_cmds, CmdFileTo, yes, DefVol

;NATIONALIZE done.

$Displayline (' done.')
$DisplayLine

$RestartLabel

;If Unattended, do not overwrite OSILocalNSAPCnfg.sys and
;OSILocalESISCnfg.sys  ADR R2.4.0000 093093

;$If SWInstal <> 1 ADR 101593

FlVer = FileVersion (OsiCnfgFile)
$If FlVer = '0'
    fCpyCnfg1 = 255
    $Goto SkipOSICnf
$EndIf

$If SWInstal <> 1	;ADR 101593


$DisplayLine
$DisplayLine
$DisplayLine

	i = 0
	$While i < 20
		i = i + 1
		$DisplayLine
	$EndWhile


;Do You want to overwrite OSILocalNSAPCnfg.sys and OSILocalESISCnfg.sys


;NATIONALIZE the next 6 lines:

$Displayline ('        The configuration files OsiLocalNSAPCnfg.sys and')
$Displayline ('        OsiLocalESISCnfg.sys are already in [Sys]<Sys>. ')
$Displayline ('                                                        ')
$Displayline ('          This floppy contains sample templates only.   ')
$Displayline ('                                                        ')
$Displayline ('                       Press AEGOAA to continue.      ')

$If not Unattended
$DisplayandWait 
$EndIf

	i = 0
	$While i < 20
		i = i + 1
		$DisplayLine
	$EndWhile


fCpyCnfg1 = UserSelectYesNo(CpyCnfgPrmpt)

SkipOSICnf:
  $If fCpyCnfg1
  ;Nationalize next line
  $Displayline ('Copying the configuration file templates to hard disk ... ')

  $If Public
     $RUN [Sys]<Sys>Lcopy.run,OSILocalESISCnfg.sys,FromUNISYS,DestPath,,yes,,no
     $RUN [Sys]<Sys>Lcopy.run,OSILocalNSAPCnfg.sys,FromUNISYS,DestPath,,yes,,no
  $Else
     $RUN [Sys]<Sys>Lcopy.run,OSILocalESISCnfg.sys,FromUNISYS,DestPath,,yes,,no
     $RUN [Sys]<Sys>Lcopy.run,OSILocalNSAPCnfg.sys,FromUNISYS,DestPath,,yes,,no
  $EndIf ;If Public

     $DisplayLine
     $DisplayLine


  ;NATIONALIZE done.
  $Displayline ('done.')

     $DisplayLine
     $DisplayLine

  $EndIf ;fCpyCnfg

$ENDIF	;SWInstal <> 1	

$RestartLabel

;New Swea
; OSITransNetCnfg.sys installation.

;This is the first time this file has been used.
;The file will have to be copied for all types of installations.
;ADR R2.4.0000 093093

FlVer = FileVersion (OsiCnfgTFile)
$If FlVer = '0'
    fCpyCnfg2 = 255
    $Goto SkipOSITCnf
$EndIf

$If SWInstal = 1	;make sure file gets copied
    fCpyCnfg2 = 255
    $Goto SkipOSITCnf
$EndIf

; Ask the installer whether he wants to overwrite OSITransNetCnfg.sys


;NATIONALIZE the next 6 lines:

$Displayline ('        The configuration file OsiTransNetCnfg.sys  ')
$Displayline ('        is already in [Sys]<Sys>.                    ')
$Displayline ('                                                     ')
$Displayline ('        This floppy contains sample templates only.  ')
$Displayline ('                                                     ')
$Displayline ('                   Press AEGOAA to continue.       ')

$If not Unattended
$DisplayandWait 
$EndIf


	i = 0
	$While i < 20
		i = i + 1
		$DisplayLine
	$EndWhile

fCpyCnfg2 = UserSelectYesNo(CpyCnfgPrmpt)

SkipOSITCnf:
  $If fCpyCnfg2
  ;Nationalize next line
  $Displayline ('Copying the configuration template file to hard disk ... ')

    $If Public
      $RUN [Sys]<Sys>Lcopy.run,OSITransNetCnfg.sys,FromUNISYS,DestPath,,yes,,no
    $Else
      $RUN [Sys]<Sys>Lcopy.run,OSITransNetCnfg.sys,FromUNISYS,DestPath,,yes,,no
    $EndIf ;If Public

     $DisplayLine
     $DisplayLine


    ;NATIONALIZE done.
    $Displayline ('done.')

     $DisplayLine
     $DisplayLine

  $EndIf ;If fCpyCnfg2

;New Swea End, See also DeAssign

$RestartLabel

;    Ask The installer to put in the next floppy (if its a 5)
;	Also check for Unattended mode

$If  MediaCheck = 1 AND InstallType <> 2 AND SWInstal <> 1
   $NextFloppy (FloppySpec)
$Endif     ; MediaCheck = 1 and InstallType <> 2

$DeAssign(PtrNameMsg)
$DeAssign(RelMsg)
$DeAssign(RifPrintMsg)
$DeAssign(RifViewMsg)
$DeAssign(OsiCnfgFile)
$DeAssign(OSICnfgTFile)
$DeAssign(FloppySpec)
$DeAssign(fCpyCnfg2)

	i = 0
	$While i < 20
		i = i + 1
		$DisplayLine
	$EndWhile


$RestartLabel

;compare the versions of STI.run 

NewSTIRnFil = Concatstrings(FromUNISYS,'STI.run')
FlVer = FileVersion (OldSTIRnFil)

$If FlVer = '0'
    fNoSTI = 0
    $Goto SkipSTICheck
$EndIf

$DisplayLine (CheckingSTI)

$DisplayLine
$DisplayLine
$DisplayLine
$DisplayLine
$DisplayLine
$DisplayLine

y = FileVersion (NewSTIRnFil)

;Fix to work with old STI, version 1.1.1
n = CopyString(FlVer,0,1)	;1st char

$If n = '1'
    fNoSTI = 0
    $Goto SkipSTICheck
$EndIf

n = CopyString(FlVer,1,1)

$If n = '1'
    fNoSTI = 0
    $Goto SkipSTICheck
$EndIf

n2 = CopyString(y,1,1)

n3 = CopyString(FlVer,3,1)
n4 = CopyString(y,3,1)

n5 = CopyString(FlVer,5,4)
n6 = CopyString(y,5,4)

totl = concatstrings (n,n3)
totl2 = concatstrings (totl,n5)

totl3 = concatstrings (n2,n4)
totl4 = concatstrings (totl3,n6)

a = StrToNum(totl2)
b = StrToNum(totl4)

;If the version of STI.run in [Sys]<Sys> is a higher version number
;give the customer the option of overwriting or not
;only if not Unattended  ADR R2.4.0000 093093

fNoSTI = 0

$If a > b AND SWInstal <> 1

;NATIONALIZE Next four lines:

$Displayline ('                A newer version of STI is installed     ')
$Displayline ('                       at this workstation.             ')
$Displayline ('                                                        ')
$Displayline ('                       Press AEGOAA to continue.      ')
$DisplayLine

	$If not Unattended
		$DisplayandWait 
	$EndIf

		i = 0
		$While (i < 20)
			i = i + 1
			$DisplayLine
		$EndWhile

	err = UserSelectYesNo (warningmsg)

	$If not err
	   fNoSTI = 255
    $Endif

$EndIf	;If a > b AND SWInstal <> 1

SkipSTICheck:

$If fNoSTI
	  $Displayline (CnclMsgSTI)

	  $DisplayLine
	  $DisplayLine

$Else
      ;Install STI on the system

	  $DisplayLine
	  $DisplayLine

      $Display (CpyMsg)

      $If Public

        ;Copy files to <Sys> for Public installation

        $Run [Sys]<Sys>Lcopy.run,STI.cmds,FromSys,DestPath,,yes,,no
		$Run [Sys]<Sys>Lcopy.run,STI.run,FromUNISYS,DestPath,,yes,,no
		$Run [Sys]<Sys>Lcopy.run,DinsSTI.run,FromUNISYS,DestPath,,yes,,no
		$Run [Sys]<Sys>Lcopy.run,STITxt.bin,FromUNISYS,DestPath,,yes,,no

	  $Else
		$Run [Sys]<Sys>Lcopy.run,STI.run,FromUNISYS,DestPath,,yes,,no
		$Run [Sys]<Sys>Lcopy.run,DinsSTI.run,FromUNISYS,DestPath,,yes,,no
		$Run [Sys]<Sys>Lcopy.run,STITxt.bin,FromUNISYS,DestPath,,yes,,no

      $EndIf	;If Public

$EndIf	;If fNoSTI	ADR  11293

$DeAssign(CpyMsg)
$DeAssign(CheckingSTI)
$DeAssign(OldSTIRnFil)   
$DeAssign(warningmsg)

;NATIONALIZE done.
$Displayline (' done.')

	  $DisplayLine
	  $DisplayLine


$RestartLabel

; STICnfg.sys installation.
;This is the first time this file has been used.
;The file will have to be copied for all types of installations.
;ADR R2.4.0000 093093


FlVer = FileVersion (STICnfgFile)
$If FlVer = '0'
    fCpyCnfg3 = 255
    $Goto SkipSTICnf
$EndIf

$If SWInstal = 1	;make sure file gets copied
    fCpyCnfg3 = 255
    $Goto SkipSTICnf
$EndIf

	i = 0
	$While i < 20
		i = i + 1
		$DisplayLine
	$EndWhile


;    Ask the installer if he wants to overwrite STICnfg.sys


;NATIONALIZE the next 6 lines:

$Displayline ('       The configuration file STICnfg.sys            ')
$Displayline ('       already exists in [Sys]<Sys>.                 ')
$Displayline ('                                                     ')
$Displayline ('        Installation files are sample templates only.')
$Displayline ('                                                     ')
$Displayline ('                   Press AEGOAA to continue.       ')

	$If not Unattended
		$DisplayandWait 
	$EndIf

	i = 0
	$While i < 20
		i = i + 1
		$DisplayLine
	$EndWhile

fCpyCnfg3 = UserSelectYesNo(CpyCnfgPrmpt)

SkipSTICnf:
  $If fCpyCnfg3
  ;Nationalize next line
  $Displayline ('Copying the configuration file template to hard disk ... ')

     $If Public
       $RUN [Sys]<Sys>Lcopy.run,STICnfg.sys,FromUNISYS,DestPath,,yes,,no  
     $Else
       $RUN [Sys]<Sys>Lcopy.run,STICnfg.sys,FromUNISYS,DestPath,,yes,,no
     $EndIf ;If Public

  $EndIf ;If fCpyCnfg3

$DeAssign(CpyCnfgPrmpt)
$DeAssign(fCpyCnfg3)
$DeAssign(STICnfgFile)

     $DisplayLine
     $DisplayLine

  ;NATIONALIZE done.
  $Displayline ('done.')


	  $DisplayLine
	  $DisplayLine

      $Display (CmdMsg)

$If Public

;Remove the commands from sys.cmds

        CmdFileTo = '[Sys]<Sys>sys.cmds'

$Run ([Sys]<Sys>CmdFileEditor.run, 'Remove Command', 'RC'),  
      'Install STI', CmdFileTo, yes, DefVol
$Run ([Sys]<Sys>CmdFileEditor.run, 'Remove Command', 'RC'),  
      'Deinstall STI', CmdFileTo, yes, DefVol

;Now add commands to cluster.cmds

        CmdFileTo = '[Sys]<Sys>Cluster.cmds'

$EndIf   	;If Public
 
      STI_cmds = ConcatStrings(FromSys,'STI.cmds')
  	  $Run ([Sys]<Sys>CmdFileEditor.run, 'Merge Command Files', 'MC'), 
	  	   STI_cmds, CmdFileTo, yes, DefVol

;NATIONALIZE done.
$Displayline (' done.')

	  $DisplayLine
	  $DisplayLine


$Deassign(CmdMsg)
$Deassign(CnclMsgSTI)

$RestartLabel


;add the OTL, and STI requests to Request.sys regardless

	$Display (RequestMsg)

	$If Public

        ;Copy Request files to <Sys> for Public installation
        $Run [Sys]<Sys>Lcopy.run,Request.BOTL.sys,FromSys,DestPath,,yes,,no
		$Run [Sys]<Sys>Lcopy.run,Request.STI.sys,FromSys,DestPath,,yes,,no

 	$EndIf	;If Public


	ReqFile = ConcatStrings(DestPath,'Request.sys') 
	BOTLReqFile = ConcatStrings(FromSys,'Request.BOTL.sys')
    STIReqFile = ConcatStrings(FromSys,'Request.STI.sys')
	Req_Save = ConcatStrings(DestPath,'SAVE>Request.sys') 

$IF Public 

;NATIONALIZE COMMAND NAME (COPY) IF NECESSARY:

$Command Copy,ReqFile,Req_Save,'Yes'


	      $Run [Sys]<Sys>ListRqSet.run,(ReqFile,   
		               	 BOTLReqFile), [scr]<$>req.txt
		  $Run [Sys]<Sys>MakeRqSet.run, [scr]<$>req.txt, ReqFile

	      $Run [Sys]<Sys>ListRqSet.run,(ReqFile,   
		               	 STIReqFile), [scr]<$>req.txt
		  $Run [Sys]<Sys>MakeRqSet.run, [scr]<$>req.txt, ReqFile

         ;NATIONALIZE COMMAND NAME (DELETE) IF NECESSARY:

         $Command Delete,[scr]<$>req.txt
    
$Else

;NATIONALIZE COMMAND NAME (COPY) IF NECESSARY:

$Command Copy,ReqFile,Req_Save,'Yes'


	      $Run [Sys]<Sys>ListRqSet.run,(ReqFile,   
		               	 BOTLReqFile), [scr]<$>req.txt
		  $Run [Sys]<Sys>MakeRqSet.run, [scr]<$>req.txt, ReqFile

	      $Run [Sys]<Sys>ListRqSet.run,(ReqFile,   
		               	 STIReqFile), [scr]<$>req.txt
		  $Run [Sys]<Sys>MakeRqSet.run, [scr]<$>req.txt, ReqFile

         ;NATIONALIZE COMMAND NAME (DELETE) IF NECESSARY:

         $Command Delete,[scr]<$>req.txt

$EndIf        ;If Public
 
;NATIONALIZE done.
$Displayline (' done.')


	$DisplayLine
	$DisplayLine

$RestartLabel


;************************************************************************
;      Scroll several lines on the screen so messages look better
;************************************************************************

	i = 0
	$While i < 20
		i = i + 1
		$DisplayLine
	$EndWhile

$Restartlabel



$Deassign (Req_Save)
$Deassign (RequestMsg)

$Path,DefVol,Sys

;***************************************************************************
; The use of display and wait will cause a hang in attended or SWD mode so
; those conditions must be tested for.                          
;***************************************************************************
End_of_file:
 

;Remind the customer to reboot to activate the updates to request.sys

i = 0

	$While (i < 12)
		i = i + 1
		$DisplayLine
	$EndWhile

		$DisplayLine
 
    ;NATIONALIZE BANNER:
$Displayline (' ')
$Displayline ('                                                            ')
$Displayline ('         The Installation of CTOS OTL is complete.          ')
$Displayline ('                                                            ')
$Displayline ('   If you have been using earlier versions of this product  ')
$Displayline ('   you may need to change your Jcl file.                    ')
$Displayline ('                                                            ')
$Displayline ('   You may have to modify OSITransNetCnfg.sys and           ')
$Displayline ('   STICnfg.sys files before using the product.              ')
$Displayline ('                                                            ')
$Displayline ('   You may wish to install the Ethernet Data Link Layer,    ')
$Displayline ('   or the Token Ring Data Link Layer at this time.          ')
$Displayline ('                                                            ')
$Displayline ('  When installation is complete, please reboot your system. ')
$Displayline ('                                                            ')
$Displayline ('               AE     Press GO to continue.     AA              ')
$Displayline ('                                                            ')
$Displayline (' ')

		$DisplayLine

	$If not Unattended
		$Displayandwait 
	$EndIf

$Path, Sys, Sys
$PauseOn
$END