SaveVidLevel = VideoLevel
EchoOff

; B24Debugger>Install.jcl
; Install the B24 Debugger subpackage

; Except for yesno strings, these two messages are the only nationalizable
; strings in this file.
ErrorMsg     = 'Cannot access B24Debugger>InstallMsg.bin'
FirstDisk    = 'Real Mode OS Diskette 4 of 4 (B25R344)'

FromFloppy   = 0
FromServer   = 2
TotalNoise   = 0
TotalSilence = 2
NotFound     = 65535
ClearScreen  = 'PF'

If SaveVidLevel = TotalNoise
   Display(ClearScreen)
EndIf

ToSpec       = ConcatStrings(VolumeTo, DirectoryTo)
FloppySpec   = ConcatStrings(DeviceFrom, '<CTOS>Debuggerv1.sys')
DbgFileSpec  = ConcatStrings(DeviceFrom, '<DebugFile>*')

If InstallType = FromFloppy
   NextFloppy(FirstDisk)
EndIf

InitErc = InitMsgFile(MsgFile)
If InitErc <> 0
   DisplayLine(ErrorMsg)
   Cancel
EndIf

If InstallType = FromServer
   Msg = GetMsg(2)
   DisplayLine(Msg)
   DisplayLine
   Msg = GetMsg(4)
   DisplayAndWait(Msg)
   Cancel
EndIf

If Not Public
   Msg = GetMsg(3)
   DisplayLine(Msg)
   DisplayLine
   Msg = GetMsg(4)
   DisplayAndWait(Msg)
   Cancel
EndIf

Display(ClearScreen)
Msg = GetMsg(7)
DisplayLine(Msg)
Msg = GetMsg(8)
DisplayLine(Msg)
Msg = GetMsg(9)
DisplayLine(Msg)
Msg = GetMsg(10)
DisplayLine(Msg)
Msg = GetMsg(11)
DisplayLine(Msg)
DisplayLine
Msg = GetMsg(12)
DisplayLine(Msg)
DisplayLine
Msg = GetMsg(13)
DisplayAndWait(Msg)
DisplayLine

If SaveVidLevel = TotalNoise
   EchoSome
EndIf
DisplayLine
Command Merge Command Files ,
           CmdFileFrom      ,
           CmdFileTo        ,
           Yes              ,
           VolumeTo
DisplayLine
Command LCopy         ,
           FloppySpec ,
                      ,
           ToSpec     ,
                      ,
           Yes        ,
           No         ,
           No         ,
           Yes
DisplayLine
Command LCopy          ,
           DbgFileSpec ,
                       ,
           ToSpec      ,
                       ,
           Yes         ,
           No          ,
           No          ,
           Yes
If SaveVidLevel = TotalNoise
   EchoOff
EndIf

ChkPkgs:
DisplayLine

;B26 Debugger
Pkg = GetMsg(5)
If SubString(Pkg, Pkgs) <> NotFound
   Diskette = GetMsg(1)
   NextFloppy(Diskette)
   GoTo EndIt
EndIf

;B27 Debugger
Pkg = GetMsg(6)
If SubString(Pkg, Pkgs) <> NotFound
   Diskette = GetMsg(1)
   NextFloppy(Diskette)
   GoTo EndIt
EndIf

EndIt:

End
