SaveVidLevel = VideoLevel
EchoOff

; vDebugger>Install.jcl
; Install the Virtualmode Debugger subpackage

; Except for yesno strings  'First disk message' the following is the only 
; nationalizable string in this file.

FromCD       = 5
FromFloppy   = 0
FromServer   = 2
FloppyType   = 0
Floppy5Qtr   = 1
Floppy3Half  = 4
Flpy3HalfLo  = 3
TotalNoise   = 0


NotFound     = 65535

If InstallType = FromFloppy
   FloppyType   = DeviceType(DeviceFrom)
EndIf

; The following message is nationalizable
If FloppyType = Floppy5Qtr
   FirstDisk    = 'Virtual Mode OS Diskette 6 of 6 (B25V1066)'
Else
   If FloppyType = Floppy3Half OR FloppyType = Flpy3HalfLo
      FirstDisk    = 'Virtual Mode OS Diskette 3 of 3 (B25V1033)'
   EndIf
EndIf

ToSpec       = ConcatStrings(VolumeTo, DirectoryTo)
FloppySpec   = ConcatStrings(DeviceFrom, '<CTOS>Debugger3.3.sys')
DbgFileSpec  = ConcatStrings(DeviceFrom, '<DebugFile>*')

If InstallType = FromFloppy
   NextFloppy(FirstDisk)
EndIf

If SaveVidLevel = TotalNoise
    EchoSome
EndIf
DisplayLine
Command Merge Command Files ,
           CmdFileFrom      ,
           CmdFileTo        ,
           Yes              ,
           VolumeTo
If SaveVidLevel = TotalNoise
    EchoOff
EndIf
DisplayLine
If InstallType = FromServer
   If SaveVidLevel = TotalNoise
        EchoSome
   EndIf
   Command LCopy                                  ,
                                                  ,
              @[Scr]<$>InstallOverwriteOkFrom.fls ,
              @[Scr]<$>InstallOverwriteOkTo.fls   ,
                                                  ,
              Yes                                 ,
              No                                  ,
              No                                  ,
              Yes
Else
   If SaveVidLevel = TotalNoise
        EchoSome
   EndIf
   Command LCopy          ,
              FloppySpec  ,
                          ,
              ToSpec      ,
                          ,
              Yes         ,
              No          ,
              No          ,
              Yes
   DisplayLine
   Command LCopy          ,
              DbgFileSpec ,
                          ,
              ToSpec      ,
                          ,
              Yes         ,
              No          ,
              No          ,
              Yes
    If SaveVidLevel = TotalNoise
        EchoOff
    EndIf
EndIf

EndIt:

End
