|	.asciz "$Header: setjmp.s,v 1.1 85/04/30 17:05:15 ed Exp $"
|	.even
|setjmp, longjmp
|
|	longjmp(a, v)
|causes a "return(v)" from the
|last call to
|
|	setjmp(v)
|by restoring all the registers and
|adjusting the stack
|
|jmp_buf is set up as:
|
|	_________________
|	|	pc	|
|	-----------------
|	|	d2	|
|	-----------------
|	|	...	|
|	-----------------
|	|	d7	|
|	-----------------
|	|	a2	|
|	-----------------
|	|	...	|
|	-----------------
|	|	a7	|
|	-----------------

	.globl erm_setjmp, erm_longjmp
	.text

erm_setjmp:
	movl	sp@(4.),a0	|pointer to jmp_buf
	movl	sp@,a0@		|pc
	moveml	#/FCFC,a0@(4.)	|d2-d7, a2-a7
	clrl	d0		|return 0
	rts

erm_longjmp:
	movl	sp@(4.),a0	|pointer to jmp_buf
	movl	sp@(8.),d0	|value returned
	moveml	a0@(4.),#/FCFC	|restore d2-d7, a2-a7
	movl	a0@,sp@		|restore pc of call to setjmp to stack
	rts
