C     CM-3 (CORE 1)                                                     CM3   1 
C     GIVEN A MATRIX OF VARIABLES X, DETERMINE Z*(I,J) = F(X(I,J)), SUCHCM3   2 
C     THAT WHENEVER X(I,J) .GT. X(K,J) THEN Z*(I,J) .GT. Z*(K,J). THIS  CM3   3 
C     PROGRAM WILL MAXIMIZE THE AVERAGE CORRELATION AMONG THE SET OF    CM3   4 
C     VARIABLES SUBJECT ONLY TO THE ABOVE MONOTONE RESTRICTION. AN OP-  CM3   5 
C     TION IS INCLUDED FOR A NOMETRIC FACTOR ANALYSIS OF THE CORRELA-   CM3   6 
C     TIONS GENERATED FROM THE OPTIMALLY SCALED VARIABLES, THUS ACHIEV- CM3   7 
C     ING AN ECONOMY OF DESCRIPTION GREATER THAN THAT REALIZABLE FROM A CM3   8 
C     NONMETRIC FACTOR ANALYSIS ON THE UNSCALED SCORES. THIS PROGRAM IS CM3   9 
C     USEFUL IN THOSE CASES WHERE MODERATELY NONLINEAR RELATIONS MAY BE CM3  10 
C     PRESENT. WRITTEN IN FORTRAN IV (LEVEL G) BY LINGOES FOR THE U. OF CM3  11 
C     M. IBM 360/67 COMPUTER. THE GUTTMAN-LINGOES NONMETRIC SERIES RE-  CM3  12 
C     SEARCH IS SUPPORTED IN PART BY A GRANT FROM THE NATIONAL SCIENCE  CM3  13 
C     FOUNDATION (GS-929).  DATE = 2/15/68.                             CM3  14 
C                                                                       CM3  15 
C     DECK SET-UP FOR G-L(CM-III) -                                     CM3  16 
C                                                                       CM3  17 
C     1.  SYSTEM ID CARD/S.                                             CM3  18 
C     2.  BINARY PROGRAM.                                               CM3  19 
C     3.  TITLE CARD FOR HEADING (PUNCH A 1 IN COLUMN 1 AND ANY BCD     CM3  20 
C         TITLE IN COLUMNS 2-72).                                       CM3  21 
C     4.  PARAMETER CARD, 10 4-COLUMN FIELDS CONTAINING THE FOLLOWING   CM3  22 
C         INFORMATION SERIATUM -                                        CM3  23 
C         A)  NS=NUMBER OF OBSERVATIONS (NS .LE. 512),                  CM3  24 
C         B)  NV=NUMBER OF VARIABLES (NV .LE. 70),                      CM3  25 
C         C)  MISS=1 IF MISSING DATA EXISTS FOR 1 OR MORE VARIABLES,    CM3  26 
C             OTHERWISE SET TO ZERO OR LEAVE BLANK,                     CM3  27 
C         D)  CODE=SOME NUMERIC VALUE THAT IS UNIFORM FOR ALL VARIABLES CM3  28 
C             AND OBSERVATIONS DENOTING AN UNKNOWN SCORE (DO NOT USE A  CM3  29 
C             VALUE REPRESENTING A LEGITIMATE SCORE.  DECIMAL POINT MUSTCM3  30 
C             BE PUNCHED), IF NO MISSING INFORMATION, LEAVE BLANK,      CM3  31 
C         E)  Z=MAXIMUM CONTRIBUTION THAT ANY ONE S CAN CONTRIBUTE TO   CM3  32 
C             ANY CORRELATION ACCORDING TO FORMAT F4.3 (DO NOT PUNCH    CM3  33 
C             DECIMAL POINT).  IF FIELD LEFT BLANK Z=.500.  RECOM-      CM3  34 
C             MENDED VALUE FOR Z,IN GENERAL,IS 5/NS IF COMMENT IS       CM3  35 
C             PRINTED OUT THAT SOME OBSERVATION IS AN OUTLIER,          CM3  36 
C         F)  NMFA=0 OR BLANK IF A NONMETRIC FACTORING IS TO BE DONE ON CM3  37 
C             THE TRANSFORMED X'S, 1 IF NOT DESIRED,                    CM3  38 
C         G)  IF NMFA=0, PUNCH NUMBER OF ITERATIONS DESIRED.  IF BLANK          
C             OR ZERO, NITER IS SET TO 25,                                      
C         H)  MIND=MINIMUM NUMBER OF DIMENSIONS DESIRED, IF BLANK OR            
C             ZERO MIND IS SET TO 1,                                            
C         I)  NDIM=MAXIMUM NUMBER OF DIMENSIONS DESIRED, IF BLANK OR            
C             ZERO PROGRAM WILL DETERMINE,                                      
C         J)  IFC=1 IF SSA COORDINATES ARE TO BE PUNCHED FOR 2 OR MORE          
C             DIMENSIONS.  IFC=-1 WHEN RE-SCALED SCORES AS WELL AS CO-          
C             ORDINATES ARE TO BE PUNCHED.  THE FIRST CARD WILL CONTAIN         
C             A SEQUENCE NUMBER IN COLUMNS 1-4 & 9 X VALUES, WHILE SUB-         
C             SEQUENT CARDS (IF ANY) WILL CONTAIN 10 X VALUES PUNCHED           
C             ACCORDING TO FORMAT F7.4.  IFC=0 OR BLANK IF NO PUNCHING          
C             AT ALL IS DESIRED.                                                
C     5.  FORMAT (DESCRIBING IN F-FORMAT HOW DATA HAS BEEN PUNCHED).    CM3  39 
C     6.  DATA (PUNCH X VALUES, WHERE EACH CARD OR SET OF CARDS REPRE-  CM3  40 
C         SENTS ONE OBSERVATION AND THE COLUMNS REPRESENT THE X'S, IN   CM3  41 
C         COLS. 1-72. 73-80 MAY OPTIONALLY BE USED FOR ID INFORMATION). CM3  42 
C     7.  TITLE CARD FOR SSA-III OUTPUT IF NMFA=0, OTHERWISE OMIT.      CM3  43 
C     8.  REPEAT ITEMS 3-6/7 FOR ADDITIONAL RUNS.                       CM3  44 
C                                                                       CM3  45 
C     *** REFERENCES - LINGOES, J. C. AND GUTTMAN, L., NOMETRIC FACTOR  CM3  46 
C                        ANALYSIS - A RANK REDUCING ALTERNATIVE TO LIN- CM3  47 
C                        EAR FACTOR ANALYSIS. MULT. BEHAV. RES., 1967,  CM3  48 
C                        2, 485-505.                                    CM3  49 
C                      LINGOES, J. C., AN IBM 360/67 PROGRAM FOR GUTTMANCM3  50 
C                        -LINGOES CONJOINT MEASUREMENT - III. BEHAV.    CM3  51 
C                        SCI., 1968, 13, 421-422.                       CM3  52 
C                                                                       CM3  53 
C     *** OBSERVE STARRED COMMENT CARDS FOR CONVERSIONS TO OTHER SYSTEMSCM3  54 
C                                                                       CM3  55 
      DIMENSION X(512,70), INDI(512,70), NOTIES(70,261), INDJ(512), SSQ(CM3  56 
     1512), SUM(70), FMT(18), NT(70), R(70,261)                         CM3  57 
      EQUIVALENCE (SUM,NT), (NOTIES,R)                                  CM3  59 
C                                                                       CM3  60 
C     SUBROUTINES NEEDED FOR CORE 1 = ORDER AND MXOUT                   CM3  61 
C                                                                       CM3  62 
      CALL REWIND (3)                                                   CM3  63 
C     *** TAPE ASSIGNMENTS ***                                          CM3  64 
      ITAPE=5                                                           CM3  65 
      JTAPE=6                                                           CM3  66 
C     SUBROUTINE DIMENSIONING                                           CM3  67 
      MD=70                                                             CM3  68 
C     INPUT TITLE, PARAMETERS, FORMAT, AND DATA                         CM3  69 
1     READ (ITAPE,69)                                                   CM3  70 
      MT=1                                                              CM3  71 
      READ (ITAPE,70) NS,NV,MISS,CODE,Z,NMFA,NITER,MIND,NDIM,IFC        CM3  72 
      READ (ITAPE,71) (FMT(J),J=1,18)                                   CM3  73 
      DO 2 I=1,NS                                                       CM3  74 
2     READ (ITAPE,FMT) (X(I,J),J=1,NV)                                  CM3  75 
C     CHECK FOR MISSING DATA AND SUBSTITUTE MEANS                       CM3  76 
      IF (MISS) 3,9,3                                                   CM3  77 
3     DO 8 J=1,NV                                                       CM3  78 
      A=0.                                                              CM3  79 
      B=0.                                                              CM3  80 
      DO 5 I=1,NS                                                       CM3  81 
      IF (X(I,J)-CODE) 4,5,4                                            CM3  82 
4     A=A+X(I,J)                                                        CM3  83 
      B=B+1.                                                            CM3  84 
5     CONTINUE                                                          CM3  85 
      A=A/B                                                             CM3  86 
      DO 7 I=1,NS                                                       CM3  87 
      IF (X(I,J)-CODE) 7,6,7                                            CM3  88 
6     X(I,J)=A                                                          CM3  89 
7     CONTINUE                                                          CM3  90 
8     CONTINUE                                                          CM3  91 
C     CONVERT SCORES TO UNITARY STANDARD MEASURE                        CM3  92 
9     FNS=NS                                                            CM3  93 
      IF (Z) 11,10,11                                                   CM3  94 
10    Z=SQRT(FNS*.5)                                                    CM3  95 
      GO TO 12                                                          CM3  96 
11    Z=SQRT(FNS*Z)                                                     CM3  97 
12    DO 14 J=1,NV                                                      CM3  98 
      SUM(J)=0.                                                         CM3  99 
      SSQ(J)=0.                                                         CM3 100 
      DO 13 I=1,NS                                                      CM3 101 
      SUM(J)=SUM(J)+X(I,J)                                              CM3 102 
13    SSQ(J)=SSQ(J)+X(I,J)**2                                           CM3 103 
      SUM(J)=SUM(J)/FNS                                                 CM3 104 
      SSQ(J)=SQRT(SSQ(J)/FNS-SUM(J)**2)                                 CM3 105 
      DO 14 K=1,NS                                                      CM3 106 
14    X(K,J)=(X(K,J)-SUM(J))/SSQ(J)                                     CM3 107 
C     PRINT MEANS AND STANDARD DEVIATIONS                               CM3 108 
      WRITE (JTAPE,69)                                                  CM3 109 
      WRITE (JTAPE,72) (SUM(J),J=1,NV)                                  CM3 110 
      WRITE (JTAPE,73) (SSQ(J),J=1,NV)                                  CM3 111 
C     COMPUTE INTERCORRELATIONS                                         CM3 112 
      DO 15 I=1,NV                                                      CM3 113 
      DO 15 J=1,I                                                       CM3 114 
15    R(I,J)=0.                                                         CM3 115 
      DO 16 I=1,NS                                                      CM3 116 
      DO 16 J=1,NV                                                      CM3 117 
      DO 16 K=1,J                                                       CM3 118 
16    R(J,K)=R(J,K)+X(I,J)*X(I,K)                                       CM3 119 
      DO 17 I=1,NV                                                      CM3 120 
      DO 17 J=1,I                                                       CM3 121 
      R(I,J)=R(I,J)/FNS                                                 CM3 122 
17    R(J,I)=R(I,J)                                                     CM3 123 
C     PRINT CORRELATION MATRIX                                          CM3 124 
      CALL MXOUT (R,NV,0,MD)                                            CM3 125 
C     REFLECT MATRIX TO POSITIVE MANIFOLD                               CM3 126 
      B=0.                                                              CM3 127 
      NVM1=NV-1                                                         CM3 128 
      DO 18 I=1,NVM1                                                    CM3 129 
      IP1=I+1                                                           CM3 130 
      DO 18 J=IP1,NV                                                    CM3 131 
18    B=B+R(I,J)                                                        CM3 132 
19    K=0                                                               CM3 133 
      DO 23 J=1,NV                                                      CM3 134 
      A=B                                                               CM3 135 
      DO 21 I=1,NV                                                      CM3 136 
      IF (I-J) 20,21,20                                                 CM3 137 
20    A=A-R(I,J)                                                        CM3 138 
21    CONTINUE                                                          CM3 139 
      IF (A.LE.B) GO TO 23                                              CM3 140 
      B=A                                                               CM3 141 
      K=1                                                               CM3 142 
      SSQ(J)=-SSQ(J)                                                    CM3 143 
      DO 22 I=1,NV                                                      CM3 144 
      R(I,J)=-R(I,J)                                                    CM3 145 
22    R(J,I)=R(I,J)                                                     CM3 146 
23    CONTINUE                                                          CM3 147 
      IF (K) 19,24,19                                                   CM3 148 
C     COMPUTE MEAN /R/                                                  CM3 149 
24    A=0.                                                              CM3 150 
      DO 25 I=1,NVM1                                                    CM3 151 
      IP1=I+1                                                           CM3 152 
      DO 25 J=IP1,NV                                                    CM3 153 
25    A=A+ABS(R(I,J))                                                   CM3 154 
      FNV=NV                                                            CM3 155 
      TN=(FNV*(FNV-1.))/2.                                              CM3 156 
      A=A/TN                                                            CM3 157 
C     REFLECT VARIABLES. PRINT REFLECTED VARIABLE NUMBERS AND MEAN /R/  CM3 158 
      WRITE (JTAPE,74)                                                  CM3 159 
      K=0                                                               CM3 160 
      DO 27 J=1,NV                                                      CM3 161 
      IF (SSQ(J).GE.0) GO TO 27                                         CM3 162 
      WRITE (JTAPE,75) J                                                CM3 163 
      K=1                                                               CM3 164 
      DO 26 I=1,NS                                                      CM3 165 
26    X(I,J)=-X(I,J)                                                    CM3 166 
27    CONTINUE                                                          CM3 167 
      IF (K) 29,28,29                                                   CM3 168 
28    WRITE (JTAPE,76)                                                  CM3 169 
29    WRITE (JTAPE,77) A                                                CM3 170 
C     ORDER EACH VARIABLE                                               CM3 171 
C     *** USE ORDER SUBROUTINE ***                                      CM3 172 
      DO 30 J=1,NV                                                      CM3 173 
30    CALL ORDER (-1,NS,X(1,J),1,INDI(1,J))                             CM3 174 
C     DETERMINE IF TIES EXIST IN INPUT DATA                             CM3 175 
      NOT=0                                                             CM3 176 
      DO 37 J=1,NV                                                      CM3 177 
      NT(J)=0                                                           CM3 178 
      JJ=1                                                              CM3 179 
      II=-1                                                             CM3 180 
      KK=JJ                                                             CM3 181 
31    LL=1                                                              CM3 182 
      MM=INDI(JJ,J)                                                     CM3 183 
32    KK=KK+1                                                           CM3 184 
      NN=INDI(KK,J)                                                     CM3 185 
      IF (X(MM,J)-X(NN,J)) 34,33,34                                     CM3 186 
33    LL=LL+1                                                           CM3 187 
      NOT=NOT+1                                                         CM3 188 
      IF (KK-NS) 32,35,35                                               CM3 189 
34    IF (LL-2) 36,35,35                                                CM3 190 
35    II=II+2                                                           CM3 191 
      NT(J)=NT(J)+2                                                     CM3 192 
      NOTIES(J,II)=LL                                                   CM3 193 
      NOTIES(J,II+1)=JJ                                                 CM3 194 
36    JJ=KK                                                             CM3 195 
      IF (JJ-NS) 31,37,37                                               CM3 196 
37    CONTINUE                                                          CM3 197 
C     INITIALIZATION                                                    CM3 198 
      ITER=0                                                            CM3 199 
      PRER=1.                                                           CM3 200 
      ASSIGN 41 TO N1                                                   CM3 201 
C     BEGIN LEAST-SQUARES-RANK-IMAGES ITERATIONS                        CM3 202 
38    ITER=ITER+1                                                       CM3 203 
C     COMPUTE U(I)                                                      CM3 204 
      A=0.                                                              CM3 205 
      DO 40 I=1,NS                                                      CM3 206 
      SSQ(I)=0.                                                         CM3 207 
      DO 39 J=1,NV                                                      CM3 208 
39    SSQ(I)=SSQ(I)+X(I,J)                                              CM3 209 
      SSQ(I)=SSQ(I)/FNV                                                 CM3 210 
40    A=A+SSQ(I)                                                        CM3 211 
      B=A/FNS                                                                   
      A=0.                                                                      
      DO 90 I=1,NS                                                              
      SSQ(I)=SSQ(I)-B                                                           
   90 A=A+SSQ(I)**2                                                             
C     ORDER U(I)                                                        CM3 212 
      GO TO N1, (41,42)                                                 CM3 213 
41    CALL ORDER (0,0,SSQ,1,INDJ)                                       CM3 214 
      ASSIGN 42 TO N1                                                   CM3 215 
      GO TO 43                                                          CM3 216 
42    CALL ORDER (1,0,SSQ,1,INDJ)                                       CM3 217 
C     COMPUTE RANK IMAGES OF X                                          CM3 218 
43    DO 44 J=1,NV                                                      CM3 219 
      DO 44 I=1,NS                                                      CM3 220 
44    X(INDI(I,J),J)=SSQ(INDJ(I))                                       CM3 221 
C     COMPUTE COEFFICIENT OF ALIENATION                                 CM3 222 
C     BASED ON UNTIED VALUES                                            CM3 223 
      B=0.                                                              CM3 224 
      DO 45 J=1,NV                                                      CM3 225 
      DO 45 I=1,NS                                                      CM3 226 
45    B=B+X(I,J)*SSQ(I)                                                 CM3 227 
      CAL=SQRT(ABS(1.-(B/(FNV*A))**2))                                  CM3 228 
C     TIE X VALUES IF TIES EXIST                                        CM3 229 
      IF (NOT) 46,55,46                                                 CM3 230 
46    DO 51 J=1,NV                                                      CM3 231 
      IF (NT(J)) 47,51,47                                               CM3 232 
47    KK=NT(J)                                                          CM3 233 
      DO 50 I=1,KK,2                                                    CM3 234 
      LL=NOTIES(J,I)                                                    CM3 235 
      MM=NOTIES(J,I+1)                                                  CM3 236 
      NN=MM                                                             CM3 237 
      B=0.                                                              CM3 238 
      DO 48 K=1,LL                                                      CM3 239 
      JJ=INDI(NN,J)                                                     CM3 240 
      B=B+X(JJ,J)                                                       CM3 241 
48    NN=NN+1                                                           CM3 242 
      NN=MM                                                             CM3 243 
      B=B/FLOAT(LL)                                                     CM3 244 
      DO 49 L=1,LL                                                      CM3 245 
      JJ=INDI(NN,J)                                                     CM3 246 
      X(JJ,J)=B                                                         CM3 247 
49    NN=NN+1                                                           CM3 248 
50    CONTINUE                                                          CM3 249 
51    CONTINUE                                                          CM3 250 
      DO 54 J=1,NV                                                      CM3 251 
      A=0.                                                              CM3 252 
      DO 52 I=1,NS                                                      CM3 253 
52    A=A+X(I,J)**2                                                     CM3 254 
      A=SQRT(FNS/A)                                                     CM3 255 
      DO 53 K=1,NS                                                      CM3 256 
53    X(K,J)=X(K,J)*A                                                   CM3 257 
54    CONTINUE                                                          CM3 258 
      GO TO 57                                                          CM3 259 
C     NORMALIZE TRANSFORMED SCORES                                      CM3 260 
55    A=SQRT(FNS/A)                                                     CM3 261 
      DO 56 J=1,NV                                                      CM3 262 
      DO 56 I=1,NS                                                      CM3 263 
56    X(I,J)=X(I,J)*A                                                   CM3 264 
C     TEST FOR OUTLIER                                                  CM3 265 
57    DO 58 J=1,NV                                                      CM3 266 
      DO 58 I=1,NS                                                      CM3 267 
      IF (ABS(X(I,J)).GE.Z) GO TO 59                                    CM3 268 
58    CONTINUE                                                          CM3 269 
C     TEST FOR TERMINATION                                              CM3 270 
      IF (CAL.LE.1E-04) GO TO 60                                        CM3 271 
      IF (ABS(CAL-PRER).LE.1E-06) GO TO 60                              CM3 272 
      IF (ITER.EQ.100) GO TO 60                                         CM3 273 
      PRER=CAL                                                          CM3 274 
      GO TO 38                                                          CM3 275 
C     PRINT RESULTS                                                     CM3 276 
59    WRITE (JTAPE,81) I,J                                              CM3 277 
60    II=1                                                              CM3 278 
      JJ=10                                                             CM3 279 
61    IF (NV.LT.JJ) JJ=NV                                               CM3 280 
      WRITE (JTAPE,78) II,JJ                                            CM3 281 
      DO 62 I=1,NS                                                      CM3 282 
62    WRITE (JTAPE,79) I,(X(I,J),J=II,JJ)                               CM3 283 
      IF (JJ.EQ.NV) GO TO 63                                            CM3 284 
      II=JJ+1                                                           CM3 285 
      JJ=II+9                                                           CM3 286 
      GO TO 61                                                          CM3 287 
C     PUNCH RE-SCALED SCORES                                                    
63    IF (IFC.GE.0) GO TO 83                                                    
      DO 82 I=1,NS                                                              
82    PUNCH 84, I,(X(I,J),J=1,NV)                                               
C     COMPUTE INTERCORRELATIONS AMONG SCALED VARIABLES                  CM3 288 
83    DO 64 I=1,NV                                                      CM3 289 
      DO 64 J=1,I                                                       CM3 290 
64    R(I,J)=0.                                                         CM3 291 
      DO 65 I=1,NS                                                      CM3 292 
      DO 65 J=1,NV                                                      CM3 293 
      DO 65 K=1,J                                                       CM3 294 
65    R(J,K)=R(J,K)+X(I,J)*X(I,K)                                       CM3 295 
      DO 66 I=1,NV                                                      CM3 296 
      DO 66 J=1,I                                                       CM3 297 
66    R(I,J)=R(I,J)/FNS                                                 CM3 298 
C     COMPUTE MEAN /R/                                                  CM3 299 
      A=0.                                                              CM3 300 
      DO 67 I=1,NVM1                                                    CM3 301 
      IP1=I+1                                                           CM3 302 
      DO 67 J=IP1,NV                                                    CM3 303 
67    A=A+ABS(R(J,I))                                                   CM3 304 
      A=A/TN                                                            CM3 305 
      WRITE (JTAPE,80) CAL,ITER,A                                       CM3 306 
      IF (NMFA.NE.0) GO TO 1                                            CM3 307 
      WRITE (3) NV,NITER,MIND,NDIM,NMFA,MT,IFC                          CM3 308 
      DO 68 I=1,NVM1                                                    CM3 309 
      IP1=I+1                                                           CM3 310 
68    WRITE (3) (R(J,I),J=IP1,NV)                                       CM3 311 
C     CALL ON NEXT CORE LOAD, I.E., CORE 2 OF SSA-III/IIIA. THIS IS A   CM3 312 
C     CHAIN JOB.  SUBSTITUTE YOUR OWN SUBROUTINE CALL HERE ***          CM3 313 
      CALL PUNT ('-CORE2 ',0,0)                                         CM3 314 
C     *** FORMAT STATEMENTS ***                                         CM3 315 
C                                                                       CM3 316 
69    FORMAT (72H                                                       CM3 317 
     1                 )                                                CM3 318 
70    FORMAT (3I4,2F4.3,5I4)                                            CM3 319 
71    FORMAT (18A4)                                                     CM3 320 
72    FORMAT (6H0MEANS/(10F13.3))                                       CM3 321 
73    FORMAT (20H0STANDARD DEVIATIONS/(10F13.3))                        CM3 322 
74    FORMAT (46H0THE FOLLOWING VARIABLES HAVE BEEN REFLECTED -)        CM3 323 
75    FORMAT (I6)                                                       CM3 324 
76    FORMAT (6H NONE.)                                                 CM3 325 
77    FORMAT (9H0MEAN R =,E13.6)                                        CM3 326 
78    FORMAT (43H1GUTTMAN-LINGOES CONJOINT MEASUREMENT - III/30H0MONOTONCM3 327 
     1ICALLY TRANSFORMED X'S/8H0SUBJECT,49X17HV A R I A B L E S,I3,3H TOCM3 328 
     2,I3/1H ,131(1H-))                                                 CM3 329 
79    FORMAT (I6,4X(10F12.5))                                           CM3 330 
80    FORMAT (28H0COEFFICIENT OF ALIENATION =,E13.6,5H FOR ,I3,12H ITERACM3 331 
     1TIONS./9H MEAN R =,E13.6)                                         CM3 332 
81    FORMAT (28H0OUTLIER FOUND FOR SUBJECT =,I4,15H AND VARIABLE =,I3,1CM3 333 
     1H.,23H  ITERATIONS CONCLUDED.)                                    CM3 334 
84    FORMAT (I4,9F7.4/(10F7.4))                                                
      END                                                               CM3 335-
18MSA SCALES SUBJECTED TO AN OPTIMAL CM-III SCALING.                            
  88   8                                                                        
(4X,8F2.0)                                                                      
   1 11813 1 9 7 9 8 1                                                          
   2 414 9 2 9 5 3 3 1                                                          
   3 21813 2 9 8 9 8 1                                                          
   4 11613 1 9 8 9 8 1                                                          
   5 81713 2 9 7 9 8 1                                                          
   6 31812 4 9 7 9 8 1                                                          
   7 31612 1 9 7 5 1 1                                                          
   8 21812 1 9 7 9 8 1                                                          
   9 11712 1 9 8 9 8 1                                                          
  10 21510 1 9 8 8 8 1                                                          
  11 31211 5 8 5 5 4 1                                                          
  12 71313 6 9 8 9 8 1                                                          
  13 41512 1 8 8 8 8 1                                                          
  14 51713 1 9 8 9 8 1                                                          
  15 11612 2 9 7 7 8 1                                                          
  16 112 7 2 6 5 5 3 1                                                          
  17 11312 1 8 4 9 7 1                                                          
  18 81311 7 7 7 3 2 2                                                          
  19 81612 6 8 8 9 8 2                                                          
  20 81413 7 8 8 9 8 2                                                          
  21 41313 6 7 7 9 8 2                                                          
  22 71312 7 7 7 9 8 2                                                          
  23 81712 7 9 8 9 8 2                                                          
  24 1 5 3 6 4 2 1 1 2                                                          
  25 81211 9 6 4 3 3 2                                                          
  26 81112 3 7 7 9 8 2                                                          
  27 81713 5 9 8 9 8 2                                                          
  28 31313 5 7 7 9 8 2                                                          
  29 81313 7 8 7 9 8 2                                                          
  30 81812 7 8 8 9 8 2                                                          
  31 8 9 6 8 6 3 3 4 2                                                          
  32 41313 5 6 6 9 8 2                                                          
  33 81313 7 7 8 8 8 2                                                          
  34 81713 7 9 7 9 8 2                                                          
  35 81313 7 7 6 9 7 2                                                          
  36 81713 6 9 7 9 8 2                                                          
  37 81812 7 9 7 8 8 2                                                          
  38 81712 4 9 8 9 8 2                                                          
  39 81312 7 7 8 9 8 2                                                          
  40 81312 7 7 8 7 8 2                                                          
  41 81213 6 6 7 9 8 2                                                          
  42 81212 8 8 4 9 8 2                                                          
  43 81212 6 7 8 9 8 2                                                          
  44 81313 7 7 6 9 8 2                                                          
  45 4 7 5 2 2 4 3 4 3                                                          
  46 3 9 4 5 7 2 2 6 3                                                          
  47 311 9 2 5 8 9 7 3                                                          
  48 4 5 2 6 3 6 1 6 3                                                          
  49 710 4 1 5 4 5 8 3                                                          
  50 5 6 5 7 3 6 2 2 3                                                          
  51 5 7 9 2 3 5 6 8 3                                                          
  52 5 4 4 8 3 4 2 1 3                                                          
  53 3 6 1 2 2 5 3 3 3                                                          
  54 3 410 1 5 4 5 7 3                                                          
  55 7 9 9 6 4 8 9 7 3                                                          
  56 4 5 2 2 3 5 1 7 3                                                          
  57 2 4 2 2 1 5 2 1 3                                                          
  58 7 6 5 7 3 5 2 3 3                                                          
  59 4 8 6 4 5 7 4 2 3                                                          
  60 6 4 3 9 3 3 2 1 3                                                          
  61 6 9 9 7 7 6 9 8 3                                                          
  62 4 8 8 2 5 6 3 4 3                                                          
  63 4 7 6 1 3 6 1 1 3                                                          
  64 5 5 6 5 2 2 7 8 3                                                          
  65 6 2 1 9 2 2 2 5 3                                                          
  66 7 5 310 3 2 1 1 4                                                          
  67 6 2 211 2 2 3 1 4                                                          
  68 7 3 211 1 2 1 1 4                                                          
  69 7 6 510 4 3 6 7 4                                                          
  70 6 4 8 9 3 3 7 8 4                                                          
  71 8 1 310 1 1 1 1 4                                                          
  72 6 2 111 1 1 1 1 4                                                          
  73 8 5 211 3 1 1 1 4                                                          
  74 7 3 111 1 2 1 1 4                                                          
  75 7 3 710 4 2 8 8 4                                                          
  76 8 4 410 3 2 5 7 4                                                          
  77 6 1 211 1 1 1 1 4                                                          
  78 8 2 311 1 1 1 2 4                                                          
  79 5 5 111 2 2 1 1 4                                                          
  80 5 6 1 9 2 2 4 6 4                                                          
  81 8 2 510 2 1 3 5 4                                                          
  82 7 1 111 1 1 3 1 4                                                          
  83 8 2 1 7 1 1 2 1 4                                                          
  84 6 4 311 1 1 2 1 4                                                          
  85 7 2 310 2 1 1 3 4                                                          
  86 8 6 410 2 2 1 1 4                                                          
  87 7 2 210 2 1 1 1 4                                                          
  88 5 1 110 1 1 1 1 4                                                          
1NONMETRIC FACTOR ANALYSIS OF CM-III-SCALED MSA SCALES.                         
